Sorry guys, quick and easy noob question!!

Collapse
X
 
  • Filter
  • Time
  • Show
Clear All
new posts

  • Sorry guys, quick and easy noob question!!

    I've used a 123 Block as the go to for training. I'm wondering if someone could do me a solid and provide me with a general workflow of operations for inspecting this part. At the moment I'm training myself and I've found tons of helpful info, but I never looked for a PC-DMIS WorkFlow to complete and inspection.

    Just for clarity, here's a simple example. Looking for something like:

    1. Unlock Car
    2. Get in car
    3. Put on Seat Belt
    4. Etc....

    Ya know?
    PG

    PC-DMIS 2010 MR3
    B&S Global Advantage 7-10-7
    TesaStar - SP25
    Houston, TX

  • #2
    0. Keep left pinky on LEFT CTRL and another finger on "S". CTRL + S is save and you may want to get your hand comfortable with this position. Save often as the demon will crash if you've waited too long...
    1. Probe points on a face (I would choose top)
    2. Create alignment that uses Level on the face, the direction is where the normal vector of the plane is pointing.
    3. Probe points on a face perpendicular to #1.
    4. Create alignment that uses Rotate on the face, the direction is where the normal vector of the plane is pointing.
    5. Probe points on a face perpendicular to #1 and #2.
    6. Create alignment that Origins X, Y, and Z to the corresponding faces that you would like to see your X, Y, and Z origin.
    7. Go to DCC mode and probe/measure/report whatever you desire.

    Comment


    • pguillory
      pguillory commented
      Editing a comment
      Thanks for this! Now, if you don't mind, how would I get this to match up to the CAD model of the 123 Block I imported? Just to see if my thought process is correct lol
      Last edited by pguillory; 07-30-2019, 02:22 PM. Reason: Checking my knowledge

    • JacobCheverie
      JacobCheverie commented
      Editing a comment
      pguillory You will want to define the features on your CAD first using program mode (CTRL + F4 or toolbar shortcut) by probing the model and pressing END when the # of points is sufficient for you. Set up alignments along the way by following the general steps above. Then, when you run the part on the machine in manual mode you will have to actually probe the points (in the real world) and by doing so the alignment/your features will snap to your CAD.

      Most people will use conditional statements (IF_GOTO) and comments to explain how to perform the manual alignment on the machine. The IF is usually a prompt asking if it's necessary. If not (already been done, part hasn't moved) then they jump past all that, straight into DCC mode by using a label in the code of the IF_GOTO.
      Last edited by JacobCheverie; 07-30-2019, 02:44 PM.

  • #3
    pguillory Here is a sample of a basic 123 Block code that I came up with. The values are all fake so don't get caught up in them. This will show a basic program structure. I have written a basic script that preloads all new programs with my formatting. You can learn a lot about that on this forum. Welcome to the demon.

    Code:
    STARTUP    =ALIGNMENT/START,RECALL:USE_PART_SETUP,LIST=YES
                ALIGNMENT/END
                MODE/MANUAL
                PREHIT/0.05
                RETRACT/0.05
                MOVESPEED/ 120
                FORMAT/TEXT,OPTIONS, ,HEADINGS,SYMBOLS, ;NOM,TOL,MEAS,DEV,OUTTOL, ,
                LOADPROBE/T1
                TIP/T1-A0B0, SHANKIJK=0, 0, 1, ANGLE=0
    START      =GROUP/SHOWALLPARAMS=NO
                ENDGROUP/ID=START
    $$ NO,
                ====================================================
                ------------------ Initialization ------------------
                ====================================================
    
    INPUT      =GROUP/SHOWALLPARAMS=YES
    NOINSPID     =LABEL/
    C1           =COMMENT/INPUT,NO,FULL SCREEN=NO,
                  INSPECTOR I.D.
                  IF/C1.INPUT==0
                    COMMENT/OPER,NO,FULL SCREEN=NO,AUTO-CONTINUE=NO,
                    INSPECTOR I.D. REQUIRED
                    GOTO/NOINSPID
                  END_IF/
    NOJOBNUM     =LABEL/
    C2           =COMMENT/INPUT,NO,FULL SCREEN=NO,
                  JOB #
                  IF/C2.INPUT==0
                    COMMENT/OPER,NO,FULL SCREEN=NO,AUTO-CONTINUE=NO,
                    JOB # REQUIRED
                    GOTO/NOJOBNUM
                  END_IF/
    C6           =COMMENT/YESNO,NO,FULL SCREEN=NO,AUTO-CONTINUE=NO,
                  IS PART SERIALIZED?
                  IF/C6.INPUT=="NO"
                    GOTO/L3
                  END_IF/
    C7           =COMMENT/INPUT,NO,FULL SCREEN=NO,
                  SERIAL #
    L3           =LABEL/
                ENDGROUP/ID=INPUT
    $$ NO,
                ====================================================
                -------------------- Fixturing ---------------------
                ====================================================
    
    C3         =COMMENT/YESNO,NO,FULL SCREEN=NO,AUTO-CONTINUE=NO,
                DOES THE PART NEED TO BE FIXTURED?
                IF_GOTO/C3.INPUT == "NO",GOTO = L1
                COMMENT/OPER,NO,FULL SCREEN=NO,AUTO-CONTINUE=NO,
                ENTER FIXTURING INSTRUCTIONS
                COMMENT/OPER,NO,FULL SCREEN=NO,AUTO-CONTINUE=NO,
                ENTER FIXURING IMAGE
    $$ NO,
                ====================================================
                ----------------- Manual Alignment -----------------
                ====================================================
    
    L1         =LABEL/
    C4         =COMMENT/YESNO,NO,FULL SCREEN=NO,AUTO-CONTINUE=NO,
                DOES THE PART NEED A MANUAL ALIGNMENT?
                IF_GOTO/C4.INPUT == "NO",GOTO = L2
                COMMENT/OPER,NO,FULL SCREEN=NO,AUTO-CONTINUE=NO,
                TOUCH FOUR PLACES ON THE Z+ FACE
    PLN1       =FEAT/PLANE,CARTESIAN,TRIANGLE
                THEO/<-0.01355,0.01432,0.56525>,<0,0,1>
                ACTL/<-0.01355,0.01432,0.56525>,<0,0,1>
                MEAS/PLANE,4
                  HIT/BASIC,NORMAL,<-1.0885,0.78888,0.56525>,<0,0,1>,<-1.0885,0.78888,0.56525>,USE THEO=YES
                  HIT/BASIC,NORMAL,<1.03905,0.83354,0.56525>,<0,0,1>,<1.03905,0.83354,0.56525>,USE THEO=YES
                  HIT/BASIC,NORMAL,<1.11165,-0.78537,0.56525>,<0,0,1>,<1.11165,-0.78537,0.56525>,USE THEO=YES
                  HIT/BASIC,NORMAL,<-1.11642,-0.77978,0.56525>,<0,0,1>,<-1.11642,-0.77978,0.56525>,USE THEO=YES
                ENDMEAS/
    MANUAL_1   =ALIGNMENT/START,RECALL:STARTUP,LIST=YES
                  ALIGNMENT/LEVEL,ZPLUS,PLN1
                ALIGNMENT/END
                COMMENT/OPER,NO,FULL SCREEN=NO,AUTO-CONTINUE=NO,
                TOUCH FOUR POINTS ON X+ FACE
    PLN2       =FEAT/PLANE,CARTESIAN,TRIANGLE
                THEO/<0.03425,-0.2463,0.56525>,<1,0,0>
                ACTL/<0.03425,-0.2463,0.56525>,<1,0,0>
                MEAS/PLANE,8
                  HIT/BASIC,NORMAL,<0.03425,-1.19273,1.31602>,<1,0,0>,<-0.71652,-1.19273,0.56525>,USE THEO=YES
                  HIT/BASIC,NORMAL,<0.03425,-1.35867,0.82835>,<1,0,0>,<-0.22885,-1.35867,0.56525>,USE THEO=YES
                  HIT/BASIC,NORMAL,<0.03425,-1.34402,0.21183>,<1,0,0>,<0.38767,-1.34402,0.56525>,USE THEO=YES
                  HIT/BASIC,NORMAL,<0.03425,-0.94132,-0.25088>,<1,0,0>,<0.85037,-0.94132,0.56525>,USE THEO=YES
                  HIT/BASIC,NORMAL,<0.03425,-0.63535,-0.50035>,<1,0,0>,<1.09985,-0.63535,0.56525>,USE THEO=YES
                  HIT/BASIC,NORMAL,<0.03425,1.27516,0.34449>,<1,0,0>,<0.25501,1.27516,0.56525>,USE THEO=YES
                  HIT/BASIC,NORMAL,<0.03425,1.25302,1.07938>,<1,0,0>,<-0.47988,1.25302,0.56525>,USE THEO=YES
                  HIT/BASIC,NORMAL,<0.03425,0.97352,1.49316>,<1,0,0>,<-0.89366,0.97352,0.56525>,USE THEO=YES
                ENDMEAS/
    MANUAL_2   =ALIGNMENT/START,RECALL:MANUAL_1,LIST=YES
                  ALIGNMENT/ROTATE,XPLUS,TO,PLN2,ABOUT,ZPLUS
                ALIGNMENT/END
                COMMENT/OPER,NO,FULL SCREEN=NO,AUTO-CONTINUE=NO,
                TOUCH FOUR POINTS ON Y- FACE
    PLN3       =FEAT/PLANE,CARTESIAN,TRIANGLE
                THEO/<0.07216,-0.1203,0.56525>,<0,-1,0>
                ACTL/<0.07216,-0.1203,0.56525>,<0,-1,0>
                MEAS/PLANE,8
                  HIT/BASIC,NORMAL,<-0.70844,-0.1203,-0.4999>,<0,-1,0>,<-0.70844,-1.18545,0.56525>,USE THEO=YES
                  HIT/BASIC,NORMAL,<-0.06373,-0.1203,-0.69101>,<0,-1,0>,<-0.06373,-1.37655,0.56525>,USE THEO=YES
                  HIT/BASIC,NORMAL,<0.54444,-0.1203,-0.586>,<0,-1,0>,<0.54444,-1.27155,0.56525>,USE THEO=YES
                  HIT/BASIC,NORMAL,<0.96481,-0.1203,-0.31531>,<0,-1,0>,<0.96481,-1.00086,0.56525>,USE THEO=YES
                  HIT/BASIC,NORMAL,<1.23812,-0.1203,1.29408>,<0,-1,0>,<1.23812,0.60853,0.56525>,USE THEO=YES
                  HIT/BASIC,NORMAL,<0.15063,-0.1203,2.04514>,<0,-1,0>,<0.15063,1.3596,0.56525>,USE THEO=YES
                  HIT/BASIC,NORMAL,<-0.363,-0.1203,1.92639>,<0,-1,0>,<-0.363,1.24084,0.56525>,USE THEO=YES
                  HIT/BASIC,NORMAL,<-1.1856,-0.1203,1.34861>,<0,-1,0>,<-1.1856,0.66306,0.56525>,USE THEO=YES
                ENDMEAS/
    MANUAL_3   =ALIGNMENT/START,RECALL:MANUAL_2,LIST=YES
                  ALIGNMENT/TRANS,XAXIS,PLN2
                  ALIGNMENT/TRANS,YAXIS,PLN3
                  ALIGNMENT/TRANS,ZAXIS,PLN1
                ALIGNMENT/END
    $$ NO,
                ====================================================
                ------------------- DCC Alignment ------------------
                ====================================================
    
    L2         =LABEL/
                COMMENT/OPER,NO,FULL SCREEN=NO,AUTO-CONTINUE=NO,
                ENSURE PROBE IS LOCATED AT A SAFE DISTANCE ABOVE THE PART
                ENTERING DCC MODE
                MODE/DCC
                MOVE/POINT,NORMAL,<0,0,1>
    $$ NO,
                ====================================================
                ------------------- DCC Features -------------------
                ====================================================
    
    $$ NO,
                ====================================================
                ------------------ Constructions -------------------
                ====================================================
    
    $$ NO,
                ====================================================
                ---------------- Datum Definitions -----------------
                ====================================================
    
    $$ NO,
                ====================================================
                ------------------- Measurements -------------------
                ====================================================
    
                COMMENT/REPT,
    
                "Inspector I.D. : " + C1.INPUT
                "    Job Number : " + C2.INPUT
                IF/C6.INPUT=="YES"
                  COMMENT/REPT,
                  " Serial Number : " + C7.INPUT
                END_IF/

    Comment


    • pguillory
      pguillory commented
      Editing a comment
      Thanks I'll look into this today. Huge help. And thanks for the welcome!

  • #4
    Also, keep in mind that all passing dimensions are automatically considered correct CMM programming, while all failing dimensions are obviously incorrect CMM programming as well as a total failure of your mission to inspect quality into the part.

    Comment


    • JacobCheverie
      JacobCheverie commented
      Editing a comment
      If it's red, make it green.

    • Kp61dude!
      Kp61dude! commented
      Editing a comment
      Don't inspect to "fail" inspect to "accept". Yep, that's scientifically possible!

    • Darrollh
      Darrollh commented
      Editing a comment
      Yep. I was told if the part failed then my program was wrong! This was coming from someone who had no clue. Lol.

  • #5
    If you're touching off a part to write your program, remember to clean up your vectors, so that when the CMM runs in DCC, it only moves in one axis at a time while touching off.

    (0,0,1), (0,1,0), etc. You'll get far more accurate results.

    Always touch off at the same speed the probe was calibrated.

    Crash is bad. Go slow till you're comfortable with the unit. If you're moving a long way in X or Y and you're just above the part? Maybe lock your Z. It's really easy to rotate that joystick without even realizing it.

    Ask questions here. Great bunch of folks who want to help, but you'll get a lot farther, if you give detailed information (nothing proprietary)

    Comment


    • William Johnson
      William Johnson commented
      Editing a comment
      The vectors will not always be perfect. a 45 deg will have a .7071,.7071,0 for example. Depending on position on CMM. So all hits need to approach normal to the surface. weather it is a sphere or a cylinder or a plane.That is why having a CAD model is the best way to program. It is better at the vectors being right.

    • Quality ish
      Quality ish commented
      Editing a comment
      Of course. I should have specified when taking hits perpendicular or parallel to the aligned axes.
      Last edited by Quality ish; 08-01-2019, 12:49 AM.

Related Topics

Collapse

Working...
X